Hi dk2463,
since we couldn't manage to set up remote control via TeamViewer (maybe due to a too big version mismatch or private use not beeing supported between continents or for whatever reasons) I suggest you try the following of your own:
I suppose that it is a local matter your DAP device having problems to bridge IPv6 packets WLAN <--> LAN(wired) and vice versa. In order to check if this is true I suggest you do some file copies of huge files between a WIN7 computer (call it PC1) directly connected to your router/cable modem and another WIN7 computer (call it PC2) sitting behind/wired to your DAP device thereby measuring the time it takes to complete each file copy. The connection between PC1 and PC2 has to be IPv6 only.
So first of all you have to create an IPv6 connection between PC1 and PC2. Let's assume the IPv6 address of PC2 is 2001:db8::2 and you have created a network share at PC2 called "share2", you would sit down at PC1, open a command prompt and type
net use Z: \\2001-db8--2.ipv6-literal.net\share2If you are asked for a user name and a password enter these credentials in order to successfully complete this operation. For explanation of "ipv6-literal.net" look
here. For conversion of the actual IPv6 address of PC2 you can use the aid of
this site. If drive letter Z is already in use at PC1 take another free drive letter instead.
After that at PC1 in addition to your local drives C, D, ... you should see another drive Z inside Windows explorer which actually is a network drive pointing to "share2" network share residing at PC2. If you copy files between C and Z you do this via a TCP/IPv6 SMB connection between PC1 and PC2.
In the next step at PC1 open Windows explorer and create a folder C:\TEST. Change into this folder and create a TXT file called mkfile.txt. Open this file (double click --> notepad) and copy the following contents to the file:
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set MAXSIZE=1024
set MINSIZE=1
set DEFAULTSIZE=5
set ROOT=%~dp0
set MY_NAME=%~n0
set TEMPFILE=%ROOT%__TEMPFILE__
set BUFFER=%ROOT%__BUFFERFILE__
set ARGS=
:loopArgs
shift
set parm=%0
if not defined parm goto doneArgs
if not defined ARGS (
set ARGS=%parm%
) else (
set ARGS=%ARGS% %parm%
)
goto loopArgs
:doneArgs
set SYNTAX_ERROR=FALSE
call :evalArgs
if %SYNTAX_ERROR%==TRUE (
call :printUsage
goto end
)
set FILE=IAM-%SIZE%-MB
set MKFILE=%ROOT%%FILE%
echo.
echo Creating "%FILE%" [%SIZE% MB] ...
call :delFiles
set CREATE_OK=TRUE
call :createFile %SIZE%
if %CREATE_OK%==FALSE (
call :localCopyError
call :delFiles
echo.
echo Files were deleted.
goto end
) else (
echo --^> DONE^^!
)
goto end
:missingValue
if %SYNTAX_ERROR%==FALSE echo.
echo ERROR: -%1: %2 unspecified.
goto :EOF
:parmValueNotAllowed
if %SYNTAX_ERROR%==FALSE echo.
echo ERROR: %1: "%2" outside allowed interval [%3,%4].
goto :EOF
:printUsage
echo.
echo %MY_NAME% v1.0 - Creates a file of a desired size in MB
echo Copyright (C) 2014, PacketTracer
echo.
echo Syntax: %MY_NAME% [[-l size] ^| [-h]]
echo -h Shows this help.
echo -l size Size of the file ^(integer count of MB^).
echo Default: size=%DEFAULTSIZE% MB.
echo Allowed sizes: %MINSIZE% - %MAXSIZE% MB.
echo.
goto :EOF
:localCopyError
echo.
echo ^|
echo ^| ERROR: An error occured while copying files.
echo ^| Check if there is enough free space within script folder
echo ^|
echo ^| %ROOT%
echo ^|
echo v
echo ---------------------------------------------------------^> ERROR
goto :EOF
:evalArgs
set /a maxParm=0
for %%i in (%ARGS%) do (
if /i "%%i"=="-h" (
set SYNTAX_ERROR=TRUE
goto :EOF
) else (
set /a maxParm+=1
set arg[!maxParm!]=%%i
)
)
if %maxParm% EQU 0 (
set SIZE=%DEFAULTSIZE%
goto :EOF
)
set lIsSet=FALSE
set /a parmIndex=1
:loopParm
call :readArg !parmIndex!
if /i !aktParm!==-l (
if %lIsSet%==TRUE (
set SYNTAX_ERROR=TRUE
goto :EOF
)
set /a parmIndex+=1
if !parmIndex! GTR %maxParm% (
call :missingValue l size
set SYNTAX_ERROR=TRUE
goto :EOF
)
call :readArg !parmIndex!
if /i !aktParm!==-l (
call :missingValue l size
set SYNTAX_ERROR=TRUE
goto :EOF
) else (
set SIZE=!aktParm!
set valOk=FALSE
for /l %%i in (%MINSIZE%,1,%MAXSIZE%) do (
if !SIZE!==%%i set valOk=TRUE
)
if !valOk!==FALSE (
call :parmValueNotAllowed -l !SIZE! %MINSIZE% %MAXSIZE%
set SYNTAX_ERROR=TRUE
goto :EOF
) else (
set lIsSet=TRUE
)
)
) else (
set SYNTAX_ERROR=TRUE
goto :EOF
)
set /a parmIndex+=1
if %parmIndex% GTR %maxParm% (
goto :EOF
) else (
goto loopParm
)
:readArg
for /l %%p in (%1,1,%1) do set aktParm=!arg[%%p]!
goto :EOF
:clear
if exist %1 del /f %1
goto :EOF
:createFile
set dezVal=%1
set /a n=0
:binaryLoop
set /a s[%n%]=dezVal%%2
set /a dezVal=dezVal/2
if %dezVal% NEQ 0 (
set /a n+=1
goto binaryLoop
)
call :clear "%TEMPFILE%"
echo #-BIGTXTFILE-#>"%TEMPFILE%"
for /l %%i in (1,1,16) do (
call :appendFile "%TEMPFILE%" "%TEMPFILE%"
if !CREATE_OK!==FALSE goto :EOF
)
call :clear "%MKFILE%"
for /l %%i in (0,1,%n%) do (
if !s[%%i]!==1 (
if exist "%MKFILE%" (
call :appendFile "%MKFILE%" "%TEMPFILE%"
if !CREATE_OK!==FALSE goto :EOF
) else (
if %%i EQU %n% (
ren "%TEMPFILE%" "%FILE%"
) else (
copy "%TEMPFILE%" "%MKFILE%" 1>nul 2>&1
if ERRORLEVEL 1 (
set CREATE_OK=FALSE
goto :EOF
)
)
)
)
if %%i LSS %n% (
call :appendFile "%TEMPFILE%" "%TEMPFILE%"
if !CREATE_OK!==FALSE goto :EOF
)
)
call :clear "%TEMPFILE%"
goto :EOF
:appendFile
call :clear "%BUFFER%"
copy %1 /b + %2 /b "%BUFFER%" 1>nul 2>&1
if ERRORLEVEL 1 (
set CREATE_OK=FALSE
goto :EOF
)
del %1
ren "%BUFFER%" "%~nx1"
goto :EOF
:delFiles
call :clear "%TEMPFILE%"
call :clear "%MKFILE%"
call :clear "%BUFFER%"
goto :EOF
:end
ENDLOCAL
After this save and close the file.
Open a command prompt and enter:
C:
cd \TEST
ren mkfile.txt mkfile.cmd
Now inside C:\TEST you have a script called mkfile.cmd you can use to create huge files of sizes between 1 MB and 1024 MB. For explanation enter
mkfile -h. For example if you enter
mkfile -l 100 the script creates a file named
IAM-100-MB of size 100 MB.
Finally you can use these files IAM-XX-MB and copy them between C:\TEST and Z: e.g.
C:
cd \TEST
copy /Y IAM-100-MB Z:\ 1>nul 2>&1
thereby measuring the time it takes.
After completion you can also copy the file in the opposite direction (again measuring the time it takes):
copy /Y Z:\IAM-100-MB .\ 1>nul 2>&1In order to measure the time a copy takes more comfortably you can also write two small scripts called
C:\TEST\forward.cmd
C:\TEST\backward.cmd
with the following contents:
forward.cmd:
@echo off
echo Start of copy: %DATE% %TIME%
echo Copying file %1 Local --^> Remote. Please wait ...
copy /Y %1 Z:\ 1>nul 2>&1
echo End of copy: %DATE% %TIME%
backward.cmd:
@echo off
echo Start of copy: %DATE% %TIME%
echo Copying file %1 Remote --^> Local. Please wait ...
copy /Y Z:\%1 .\ 1>nul 2>&1
echo End of copy: %DATE% %TIME%
(If you use a network drive letter other than Z you must adapt these scripts accordingly)
These scripts print time information straight before the start and after the end of the copy process. From file size and time difference you can easily calculate the data transfer rate in MB/sec.
You would have to call these scripts specifying the name of the file to copy (e.g. IAM-100-MB) as the first argument. For example if you create a file of size 250 MB you would have to type the following in a command prompt:
C:
cd \TEST
mkfile -l 250
forward IAM-250-MB
backward IAM-250-MB
If you want you can post the results here for further evaluation.
For comparison you can also repeat these copy tests using an IPv4 connection between PC1 and PC2. If the IPv4 address of PC2 is assumed to be 192.168.0.2, you would have to type the following commands inside a command prompt at PC1:
net use Z: /delete
net use Z: \\192.168.0.2\share2
(... again entering user and password if needed).
Now you have an IPv4 connection between PC1 and PC2 and you could repeat the copy tests as described above. They should be much faster now if my theory is correct that DAP-1525 has problems with bridging of IPv6 packets.
PT
EDIT:Before you do all this first of all it might be helpful to show us your IP/IPv6 configuration of the PCs I called PC1 and PC2 above. To do so at each of these PCs open a command prompt and enter the command
ipconfig /all. You can mark the output text of this command with your mouse, then copy it by pressing ENTER and then paste it here via CTRL+V. If this doesn't work you first have to activate "Quick Edit Mode" in the properties of an open command prompt (click on the command prompt symbol residing on the left top corner of an open command prompt, then select "Default values", then select options tab and activate Quick Edit mode - close and reopen the command prompt to activate the new settings)
Author
Topic: Very slow speeds on IPv6 (Read 69132 times)